How to Calculate Cumulative Percentage in Excel

To calculate a cumulative percentage in Excel, divide a running total by the grand total: =SUM($B$2:B2)/SUM($B$2:$B$6), then fill it down. Each row shows what share of the whole you've reached so far, and the last row is always 100%. This guide shows the formula step by step, a two-column version that's easier to check, a Pareto (80/20) example and a PivotTable shortcut.

What is a cumulative percentage?#

A cumulative percentage is a running share of the total. Each row adds its value to everything above it, then divides by the grand total. It answers questions like "which few categories make up 80% of complaints?" or "how far through the yearly budget are we by June?".

Here is a list of customer complaints by category, in A1:B6, already sorted from largest to smallest:

The total is 120. Late delivery alone is 48 ÷ 120 = 40%. Adding Damaged item gives 78 ÷ 120 = 65%, and so on down to 100%.

Step 1: Build a running total with SUM#

A running total adds every value from the top down to the current row. In C2, type:

=SUM($B$2:B2)

Fill it down to C6 with a double-click on the fill handle, or select C2:C6 and press Ctrl+D (Mac: ⌘D). C3 becomes =SUM($B$2:B3), C4 becomes =SUM($B$2:B4), and so on.

The trick is the mix of locked and unlocked references. $B$2 is absolute, so the start of the range stays on row 2. B2 is relative, so the end moves down one row each time. The result is 48, 78, 99, 111 and 120. The SUM function guide covers the syntax.

Step 2: Divide by the grand total#

Now divide each running total by the grand total. In D2, type:

=C2/SUM($B$2:$B$6)

Fill it down, then format D2:D6 as a percentage with Ctrl+Shift+% (Mac: Control+Shift+%) or the % button on the Home tab. Click Increase Decimal once to see one decimal place: 40.0%, 65.0%, 82.5%, 92.5% and 100.0%.

Here the whole total range is locked: $B$2:$B$6. If you forget the dollar signs, the range slides down as you fill, the total shrinks, and the last row no longer shows 100%. That final 100% is your quick check that the formulas are right.

The one-cell cumulative percentage formula#

You don't need a separate running total column. Combine both steps in one formula in D2:

=SUM($B$2:B2)/SUM($B$2:$B$6)

Fill it down. In D4, it becomes =SUM($B$2:B4)/SUM($B$2:$B$6), which is 99 ÷ 120 = 0.825, or 82.5%. That's the exercise on this page.

If you prefer to keep the total in its own cell, say B7 holds =SUM(B2:B6), the formula gets shorter: =SUM($B$2:B2)/$B$7. Remember the dollar signs on B7.

Another way: add up each row's percentage#

You can also work out each row's share of the total first, then add those shares cumulatively. This version is easy to check line by line.

1. In C2, type =B2/SUM($B$2:$B$6) and fill down. This is each category's percentage of the total: 40%, 25%, 17.5%, 10% and 7.5%.
2. In D2, type =SUM($C$2:C2) and fill down. This adds the shares: 40%, 65%, 82.5%, 92.5% and 100%.

Both methods give exactly the same answer. Use whichever is easier for your reader to follow. For the basic percentage formulas behind this, see the Excel percentage formula guide.

Using cumulative percentage for a Pareto (80/20) analysis#

A Pareto analysis finds the few categories that cause most of the total. The idea, often called the 80/20 rule, is that a small number of causes is usually behind most of the effect.

1. Sort the data from largest to smallest. Select A1:B6, go to Data > Sort, and sort by Complaints, largest to smallest. Without sorting, the cumulative percentage still works, but it won't show the biggest causes first.
2. Add the cumulative percentage column as above.
3. Read where it crosses 80%. Here, the first three categories reach 82.5%. Fixing late deliveries, damaged items and wrong items would deal with most complaints.

Excel 2016 and later can draw this as a chart: select A1:B6 and choose Insert > Statistic Chart > Pareto. The chart sorts the bars and draws the cumulative line for you.

Cumulative percentage of a target or budget#

The same pattern tracks progress towards a goal. Instead of dividing by the total of the list, divide by the target. If monthly sales are in B2:B13 and the yearly target is in F1:

=SUM($B$2:B2)/$F$1

Fill it down. By the row where this passes 100%, you've hit the target. Unlike the Pareto version, this one can end above or below 100%. For growth calculations instead, see how to increase a number by a percentage.

Cumulative percentage in a PivotTable#

If your data is in a PivotTable, you don't need formulas. Right-click any number in the Values area, choose Show Values As > % Running Total In, and pick the base field that sets the order, such as Category or Month. Sort the PivotTable first if you want a Pareto view, because the running percentage follows the order of the rows.

Practise it#

The skill that makes cumulative percentages work is locking the right half of a range. Practise relative and absolute references in a live spreadsheet: you'll lock cells with $ and fill formulas down, and each step is checked instantly. Then try the percentages and % change lesson to format results and calculate growth. Start with the exercise on this page.