How to Increase or Decrease a Number by a Percentage

To increase by percentage in Excel, multiply the number by 1 plus the percentage, like =B2*(1+C2). To decrease, multiply by 1 minus the percentage. That one pattern handles price rises, pay rises, markups, discounts and growth targets. This guide shows both formulas on real numbers, how to round the result to cents, how to apply one rate to a whole column, and the mistakes that give wrong answers.

The formulas to increase or decrease by a percentage#

Why does 1+C2 work? Excel stores 10% as 0.1, so 1+C2 is 1.1, which means "the whole amount plus 10% more". Multiplying by 1.1 adds the 10% in one step. The brackets matter: without them, =B2*1+C2 multiplies first and then adds 0.1.

Worked example: a supplier price rise#

A café's supplier sends new prices. The current price is in column B and each item's increase is in column C:

In D2, type =B2*(1+C2) and fill down with Ctrl+D (⌘D on a Mac). The results are 21.3893, 2.52 and 13.75. The first one has too many decimals for a price, which is where rounding comes in.

How to round the result to cents#

Money should usually be rounded to 2 decimal places, so the totals on an invoice match what people pay. Wrap the formula in ROUND:

=ROUND(B2*(1+C2),2)

For the coffee beans, the result is 21.39. The second argument, 2, is the number of decimal places. Formatting the cell to show 2 decimals only changes the display; ROUND changes the stored value, which is what totals use.

For prices that should always round up, such as to the next whole unit, use ROUNDUP: =ROUNDUP(B2*(1+C2),0) returns 22. The ROUND function guide and the rounding lesson cover ROUND, ROUNDUP and ROUNDDOWN side by side.

How to apply one percentage to a whole column#

When every row gets the same rise, put the rate in one cell and lock it with $ signs. With a 4% pay rise in E1 and salaries in column B:

=B2*(1+$E$1)

Fill it down, and every row uses E1. A salary of 42,000 becomes 43,680. Without the $ signs, the next row would look at E2, which is empty, and simply copy the old salary. Change E1 to 5% and the whole column updates.

To change the original numbers instead of adding a new column, use Paste Special. Type 1.04 in a spare cell and copy it. Select the salaries, open Paste Special (Ctrl+Alt+V on Windows, ⌃⌘V on a Mac), choose Multiply and click OK. Each value grows by 4% in place. Keep a copy first, because this overwrites the originals.

How to increase only some rows#

Sometimes only certain rows get the rise, for example only staff marked "Yes" for a pay review in column C. Combine the formula with IF:

=IF(C2="Yes",B2*(1+$E$1),B2)

Rows marked Yes grow by the rate in E1, and every other row keeps its old value. With a 4% rate, 42,000 becomes 43,680 for a Yes and stays 42,000 otherwise. For different rates by grade or region, look the rate up with XLOOKUP or VLOOKUP instead of using one fixed cell.

How to decrease a number by a percentage#

Decreasing works the same way with a minus sign. With a price of 200 and a 15% discount:

=B2*(1-C2)

The result is 170. This is the sale-price formula, and the guide on how to calculate a discount in Excel adds discount percentages from two prices and double discounts. If you need the price that gives a certain margin rather than a markup, that's a different formula, explained in the profit margin formula in Excel.

How to increase by a percentage over several periods#

For growth that repeats, such as a yearly rise, raise the growth factor to the number of periods:

=B2*(1+C2)^3

With 1,000 in B2 and 5% in C2, the result is about 1,157.63 after three years. That's more than 1,150, because each year's 5% is calculated on a bigger number. The same idea drives a savings goal calculator in Excel.

Common mistakes and how to reverse an increase#

These are the errors that show up most:

• Adding the percentage: =B2+C2 with 200 and 10% gives 200.1, because 10% is 0.1.
• Multiplying by the percentage only: =B2*C2 gives 20, the increase, not the new value.
• Expecting a rise and a cut to cancel out: 100 plus 10% is 110, but 110 minus 10% is 99, because the second 10% is taken from a bigger number.
• Reversing with subtraction: to find the price before a 10% rise, divide: =B2/(1+C2). With 220, that gives 200. Using =B2*(1-C2) gives 198, which is wrong.

To work out what percentage a price changed by, from the old and new values, use =(new-old)/old. The guide to the percentage formula in Excel covers that and four other common calculations, and percentage of total explains shares of a whole.

Practise it#

Increasing by a percentage is a short formula that tests love, often with rounding on top. Practise percentages and growing a number by a percent in a live spreadsheet, then try the ROUND, ROUNDUP and ROUNDDOWN lesson to get prices exact. You type each formula and it is checked instantly. Try the supplier price exercise on this page first.