How to Remove Numbers From Text in Excel

To remove numbers from text in Excel, you need a formula that throws away every digit and keeps everything else, because most versions of Excel have no single "remove digits" function. In Excel 2021 or Microsoft 365, a TEXTJOIN formula does it in one cell. In any version, ten nested SUBSTITUTE functions do the same job. This guide shows both, plus quick no-formula options and how to clean up the spaces left behind.

Which method should you use?#

Pick the method by your Excel version and whether the data will change. All the examples use this list of names with customer numbers mixed in:

If you need the opposite, keeping the numbers and removing the letters, see how to extract numbers from text.

Remove numbers with TEXTJOIN and MID (Microsoft 365)#

This formula checks each character and keeps it only if it isn't a digit. In B2:

=TRIM(TEXTJOIN("",TRUE,IF(ISERR(--MID(A2,SEQUENCE(LEN(A2)),1)),MID(A2,SEQUENCE(LEN(A2)),1),"")))

The result is Maria Lopez. Fill it down (Windows: Ctrl+D; Mac: ⌘D) and every row loses its number. SEQUENCE needs Excel 2021 or Microsoft 365.

How the formula works#

Read it from the inside out:

1. LEN(A2) counts the characters: 16 for "Maria Lopez 2041".
2. SEQUENCE(16) makes the list 1, 2, 3 … 16, one position per character.
3. MID(A2, SEQUENCE(16), 1) takes one character from each position, so you get "M", "a", "r" and so on. The MID function guide explains its three arguments.
4. -- tries to turn each character into a number. Digits become numbers; letters and spaces become #VALUE! errors.
5. ISERR(...) is TRUE for the errors, which are the characters you want to keep.
6. IF returns the character when ISERR is TRUE, and an empty string "" for each digit.
7. TEXTJOIN("",TRUE, ...) joins the kept characters with no separator and skips the empty ones. See the TEXTJOIN function guide.
8. TRIM removes the trailing space left where " 2041" used to be.

In Excel 2019, which has TEXTJOIN but not SEQUENCE, swap SEQUENCE(LEN(A2)) for ROW(INDIRECT("1:"&LEN(A2))) and confirm the formula with Ctrl+Shift+Enter.

Some current Microsoft 365 versions also include REGEXREPLACE, which can do this in one short step: =REGEXREPLACE(A2,"[0-9]",""). If your Excel shows #NAME? for it, use the TEXTJOIN formula instead.

Remove numbers in any Excel version with SUBSTITUTE#

SUBSTITUTE replaces one piece of text with another. Replace a digit with "" (nothing) and it disappears. Nest ten of them to cover 0 to 9:

=TRIM(SUBSTITUTE(SUBSTITUTE(SUBSTITUTE(SUBSTITUTE(SUBSTITUTE(SUBSTITUTE(SUBSTITUTE(SUBSTITUTE(SUBSTITUTE(SUBSTITUTE(A2,"0",""),"1",""),"2",""),"3",""),"4",""),"5",""),"6",""),"7",""),"8",""),"9",""))

It looks long, but it's ten copies of the same step. The innermost SUBSTITUTE removes every 0, the next removes every 1, and so on. For "3307 James Okafor", the result is James Okafor. This works in every version of Excel, including Excel 2010, so it's the safe choice for files you share widely.

SUBSTITUTE replaces every copy of the digit, not just the first. The SUBSTITUTE function guide covers its optional fourth argument, which replaces only one occurrence. The same idea removes any other unwanted character, as shown in how to remove characters in Excel.

Remove numbers without a formula#

For a one-off clean-up, you can skip formulas.

Flash Fill copies a pattern you type:

1. In B2, type the clean version by hand: Maria Lopez.
2. In B3, start typing James. Excel suggests the rest of the column in grey.
3. Press Enter to accept, or use Data > Flash Fill (Windows: Ctrl+E).

Check a few rows, because Flash Fill guesses the pattern and can get unusual entries wrong.

Find and Replace changes the cells in place. Excel's wildcards (* and ?) match any character, not only digits, so you must replace each digit separately:

1. Select the column and press Ctrl+H (Mac: Control+H).
2. Type 0 in Find what, leave Replace with empty, and click Replace All.
3. Repeat for 1 to 9.

Both methods give fixed values. If the source data changes, the results don't update.

Remove numbers only from the start or end#

When the number sits at one end, separated by a space, a shorter formula is enough. In Microsoft 365 or Excel 2024:

TEXTBEFORE with -1 keeps everything before the last space. TEXTAFTER keeps everything after the first space. In older versions, =MID(A3,FIND(" ",A3)+1,LEN(A3)) removes a leading number and its space. When the number always has the same length, LEFT, RIGHT and LEN work too; see how to remove the first characters.

Clean up spaces and separators left behind#

Removing digits often leaves spaces or symbols that the digits were attached to. Plan for it:

• Double and trailing spaces. "Room 12 B" becomes "Room B" with two spaces. TRIM fixes this. The guide on how to remove spaces in Excel covers non-breaking spaces that TRIM can't see.
• Separators. "INV-2026-0042" becomes "INV--". Add one more SUBSTITUTE to remove the hyphens.
• Line breaks. Imported text may hide line breaks between the name and the number. Remove them first, as shown in how to remove line breaks.
• Decimal points and signs. The formulas remove digits only, so "Size 7.5" becomes "Size ." Remove the full stop too if it doesn't belong.

When you're happy with the clean column, copy it and use Paste Special > Values to replace the formulas with plain text.

Practise it#

Text clean-up is one of the most common real tasks in Excel, and it shows up in data-entry and analyst tests. Practise cleaning messy text in a live spreadsheet with TRIM and SUBSTITUTE, then practise LEFT, RIGHT, MID and LEN to split text by position. To get comfortable with SEQUENCE and the other new functions, try the modern Excel functions lesson. Each one checks your formula as you type. Then try the exercise on this page.