The CHOOSE Function in Excel

The Excel CHOOSE function picks a value from a list by its position: give it 2 and it returns the second item. It is the quickest way to turn a number into a label, such as shift codes into shift names or month numbers into quarters, without a long chain of IFs. This guide is for beginners and covers the syntax, five practical uses, and when SWITCH or IFS is the better tool.

What does CHOOSE do in Excel?#

CHOOSE takes a position number and a list of values, and returns the value in that position.

=CHOOSE(index_num, value1, [value2], ...)

So =CHOOSE(2,"Morning","Afternoon","Night") returns Afternoon. CHOOSE works in every version of Excel, including Excel 2010, Excel for Mac and Excel for the web.

How to use CHOOSE to turn codes into labels#

The most common use is replacing numeric codes with readable names. Here is a shift rota:

Step 1: Point CHOOSE at the code#

Click C2 and type =CHOOSE(B2,. B2 holds 2, so CHOOSE will return the second value.

Step 2: List the labels in order#

Type the labels in the order of their codes, then close the bracket:

=CHOOSE(B2,"Morning","Afternoon","Night")

The result is Afternoon. Fill down with Ctrl+D (Windows) or ⌘D (Mac), and each row picks its own label.

The same formula with nested IF would be =IF(B2=1,"Morning",IF(B2=2,"Afternoon","Night")). CHOOSE is shorter and easier to extend: a fourth shift only needs one more value. Our nested IF guide explains when nesting is still the right call.

How to get the quarter from a date with CHOOSE#

CHOOSE can map 12 month numbers to 4 quarters. MONTH returns 1 to 12, and CHOOSE uses that as the position:

=CHOOSE(MONTH(A2),1,1,1,2,2,2,3,3,3,4,4,4)

For a date in February, MONTH returns 2, and the second value is 1, so the date is in Q1. Add a label with &: ="Q"&CHOOSE(MONTH(A2),1,1,1,2,2,2,3,3,3,4,4,4) returns Q1.

This really pays off for fiscal years that don't start in January. If your year starts in July, July to September is Q1 and January is Q3:

=CHOOSE(MONTH(A2),"Q3","Q3","Q3","Q4","Q4","Q4","Q1","Q1","Q1","Q2","Q2","Q2")

A February date returns Q3. You can read the whole calendar from the formula, which is hard to do with nested IFs.

How to show day names with CHOOSE and WEEKDAY#

WEEKDAY returns 1 for Sunday through 7 for Saturday (its default numbering), so CHOOSE can give each day a short name:

=CHOOSE(WEEKDAY(A2),"Sun","Mon","Tue","Wed","Thu","Fri","Sat")

For 14 February 2026, a Saturday, the result is Sat. =TEXT(A2,"ddd") gives a similar result, but CHOOSE lets you use any labels you like, such as "Weekend" for 1 and 7 and "Weekday" for the rest.

How to switch between scenarios with CHOOSE#

CHOOSE can return cell references and ranges, not just typed values. That makes it useful for scenario models. Suppose F1 holds 1, 2 or 3 for Low, Mid and High growth, and the rates are in B8, C8 and D8:

=CHOOSE(F1,B8,C8,D8)

With F1 set to 2, the formula returns the Mid rate from C8. Change F1 and every formula that uses this cell updates.

If people pick the scenario as a word, such as Low, Mid or High in H1, let MATCH turn the word into the number CHOOSE needs:

=CHOOSE(MATCH(H1,{"Low","Mid","High"},0),B8,C8,D8)

MATCH finds "Low" in position 1 of the list in curly braces, so CHOOSE returns the Low rate from B8. A word that isn't in the list makes MATCH return #N/A, which tells you straight away that the input is wrong.

It also works with whole ranges inside another function:

=SUM(CHOOSE(F1,B2:B13,C2:C13,D2:D13))

This adds column B, C or D depending on F1. Pair it with a drop-down list in F1 to build a simple "pick a scenario" switch.

Why does CHOOSE return #VALUE!?#

CHOOSE returns #VALUE! when the index number is outside the list.

• =CHOOSE(0,"a","b") returns #VALUE!, because positions start at 1.
• =CHOOSE(4,"Morning","Afternoon","Night") returns #VALUE!, because there is no fourth item.
• A text index, such as "2" typed with an apostrophe, may also cause errors. Check the cell with ISNUMBER; the IS functions guide shows how.

Decimals don't cause an error: CHOOSE cuts them to a whole number, so =CHOOSE(2.9,"a","b","c") returns b. To show a friendly message for bad codes, wrap it: =IFERROR(CHOOSE(B2,"Morning","Afternoon","Night"),"Check code").

CHOOSE vs SWITCH vs IFS: which should you use?#

Pick the function that matches the kind of input you have.

CHOOSE has no "otherwise" value, so every possible index needs an item in the list. SWITCH has a default result, which makes it safer for codes that may change. IFS handles thresholds like grade bands; see the IFS function guide for its syntax. SWITCH and IFS need Excel 2019 or later, while CHOOSE works everywhere, which matters if your file goes to people on older versions. For text-based tests, such as "does the cell contain refund?", see IF with text.

Practise it#

Try the live exercise on this page to turn shift codes into names. Then practise IS functions and SWITCH in a live spreadsheet, the closest relative of CHOOSE, and use the nested IF and IFS lesson to see when a threshold test is the better fit.